Difference between revisions of "Reference:Array"

From POV-Wiki
Jump to navigation Jump to search
m (clarity)
m (technical correction)
Line 132: Line 132:
// remove a key from a dictionary
// remove a key from a dictionary
#undef Fnord["Foo"];
#undef Fnord["Foo"]
// declare a local and un-define any global variable of same name
// declare a local and un-define any global variable of same name
#declare local.Foo = 4711;
#declare local.Foo = 4711;
#undef global.Foo;
#undef global.Foo
// mixed-type array declaration
// mixed-type array declaration

Revision as of 08:35, 6 December 2018

You may declare arrays of identifiers with up to five dimensions. Any item that can be declared as an identifier can be declared in an array. Consequential to the improvements with the classic array container topology, two New features in version 3.8 extended functionality to allow the creation of dictionary container types. Additionally arrays now support a mixed-type declaration. Dictionaries can be used for mapping string keys to arbitrary-type values. The mixed-type declaration allows the array to hold elements of different types.

Declaring Arrays

The syntax is as follows:

  #declare IDENTIFIER = array [mixed] [[ INT ]]..[ARRAY_INITIALIZER] |
  #local IDENTIFIER = array [mixed] [[ INT ]]..[ARRAY_INITIALIZER]
  #declare IDENTIFIER = dictionary; | #local IDENTIFIER = dictionary;
  Any valid array entry

Where IDENTIFIER is the name of the identifier and INT is a valid float expression, internally truncated to an integer, and used to specify the size of the array.

Note: In previous versions IDENTIFIER names were limited to 40 characters. There has been a Change removing that restriction.

See Array Initializers for more about the optional ARRAY_INITIALIZER parameter.

Consider the following example of a one-dimensional, uninitialized array:

#declare MyArray = array[10]

It declares an uninitialized array of ten elements. The elements are referenced as MyArray[0] through MyArray[9]. As yet, the type of the elements are undetermined. Once you have initialized any element of the array, all other elements can only be defined as that type. New in version 3.8 this behavior can be over-ridden by using the mixed keyword in the array declaration allowing mixed-type elements. Irregardless of whether the array elements have mixed-types or not, any attempt to reference an uninitialized element results in an error. More below:

#declare MyArray = array[10]
#declare MyArray[5] = pigment{White}     //all other elements must 
                                         //be pigments too.
#declare MyArray[2] = normal{bumps 0.2}  //generates an error
#declare Thing = MyArray[4]              //error: uninitialized array element

Multi-dimensional arrays up to five dimensions may be declared. This example ...

#declare MyGrid = array[4][5]

... declares a 20 element array of 4 rows and 5 columns. Elements are referenced from MyGrid[0][0] to MyGrid[3][4]. Although it is permissible to reference an entire array as a whole, you may not reference just one dimension of a multi-dimensional array.

#declare MyArray = array[10]
#declare MyGrid = array[4][5]
#declare YourArray = MyArray  //this is ok
#declare YourGrid = MyGrid    //so is this
#declare OneRow  = MyGrid[2]  //this is illegal

The #ifdef and #ifndef directives can be used to check whether a specific element of an array has been declared. See also: dimensions and dimension_size for additional information about the methods used to determine the size of arrays.

Large uninitialized arrays do not take much memory. Internally they are arrays of pointers so they probably use just 8 bytes per element. Once initialized with values, they consume memory depending on what they contain.

The rules for local vs global arrays are the same as any other identifier.

Note: This applies to the entire array. You cannot mix local and global elements in the same array. See #declare vs. #local for information on identifier scope.

Any legitimate use of the #declare directive can also be put into an array. In other words, you can also create multidimensional arrays by making an array of arrays.

New to version 3.8 points to also consider:

  • Array elements no longer have to be all of the same type. However, be aware that mixing elements of different types will increase memory consumption. That increased memory footprint will not revert even if the array is later set to elements all of the same type.
  • An array can be declared without specifying any dimensions; in this case the array will be one-dimensional and be able to grow in size dynamically.
  • Accessing an element beyond the nominal size of such an array will automatically increase the nominal size just enough to include that element.
  • The memory footprint may be twice as high than required for the current nominal size.
  • Growth of such an array is triggered by any access to an element beyond the nominal size, this includes tests such as #ifdef(ARRAY[INDEX]).
  • The following applies to dictionary containers only:
    • When using square bracket notation the keys do not necessarily have to be string literals, they can also be arbitrary string expressions.
    • If using dot notation the indices must follow the generic rules for identifiers.
    • Included are the two pseudo-dictionaries local and global they represent the most local and the least local or global identifiers respectively.

Additional usage examples are as follows:

// create an empty dictionary
#declare Fnord = dictionary;

// create a dictionary with elements
#declare Fnord = dictionary {
  ["Foo"]: 42,
  ["Bar"]: sphere { <0,0,0>, 1 }

// alternative
#declare Fnord = dictionary {
  .Foo: 42,
  .Bar: sphere { <0,0,0>, 1 }

// access a dictionary element
#declare Fnord["Foo"] = 42;
#declare Answer = Fnord["Foo"];

// alternative
#declare Fnord.Foo = 42;
#declare Answer = Fnord.Foo;

// test whether a dictionary contains a particular key
#ifdef (Fnord["Foo"]) ... #end
#declare FooKeyExists = defined(Fnord.Foo);

// remove a key from a dictionary
#undef Fnord["Foo"]

// declare a local and un-define any global variable of same name
#declare local.Foo = 4711;
#undef global.Foo

// mixed-type array declaration
#declare Foo = array mixed[3];
#declare Foo[0] = 42;
#declare Foo[1] = "Fnord";
#declare Foo[2] = sphere { <0,0,0>, 1 }

Array Initializers

Because it can be cumbersome to individually initialize the elements of an array, you may initialize it as it is created using array initializer syntax.

#include "colors.inc"
#declare FlagColors = array[3] {Red,White,Blue}

Multi-dimensional arrays may also be initialized this way.

#declare Digits =
array[4][10] {

The commas are required between elements and between dimensions as shown in the example.