# Reference:Transformations

The supported transformations are `rotate`

, `scale`

, and `translate`

. They are used to turn, size and move an object or texture. A transformation matrix may also be used to specify complex transformations directly. Groups of transformations may be merged together and stored in a transformation identifier.

The syntax for transformations is as follows:

TRANSFORMATION: rotate <Rotate_Amt> | scale <Scale_Amt> | translate <Translate_Amt> | transform TRANSFORM_IDENTIFIER | transform { TRANSFORMATION_BLOCK...} | matrix <Val00, Val01, Val02, Val10, Val11, Val12, Val20, Val21, Val22, Val30, Val31, Val32> TRANSFORMATION_BLOCK: TRANSFORM_IDENTIFIER | TRANSFORMATION | inverse TRANSFORM_DECLARATION: #declare IDENTIFIER = transform { TRANSFORMATION_BLOCK...} | #local IDENTIFIER = transform { TRANSFORMATION_BLOCK...}

## Translate

Items may be moved by adding a `translate`

modifier. It consists of the keyword `translate`

followed by a vector expression. The three terms of the vector specify the number of units to move in each of the x, y and z directions. Translate moves the element relative to its current position.

For example:

sphere { <10, 10, 10>, 1 pigment { Green } translate <-5, 2, 1> }

will move the sphere from the location `<10,10,10>`

to `<5,12,11>`

. It does not move it to the absolute location `<-5,2,1>`

. Translations are always relative to the item's location before the move. Translating by zero will leave the element unchanged on that axis.

For example:

sphere { <10, 10, 10>, 1 pigment { Green } translate 3*x // evaluates to <3,0,0> so move 3 units // in the x direction and none along y or z }

## Scale

You may change the size of an object or texture pattern by adding a `scale`

modifier. It consists of the keyword `scale`

followed by a vector expression. The three terms of the vector specify the amount of scaling in each of the x, y and z directions.

Uneven scaling is used to * stretch* or *squish* an element. Values larger than one stretch the element on that axis while values smaller than one are used to squish it. Scale is relative to the current element size. If the element has been previously re-sized using scale then scale will size relative to the new size. Multiple scale values may used.

For example:

sphere { <0,0,0>, 1 scale <2,1,0.5> }

will stretch and smash the sphere into an ellipsoid shape that is twice the original size along the x-direction, remains the same size in the y-direction and is half the original size in the z-direction.

If a lone float expression is specified it is promoted to a three component vector whose terms are all the same. Thus the item is uniformly scaled by the same amount in all directions.

For example:

object { MyObject scale 5 // Evaluates as <5,5,5> so uniformly scale // by 5 in every direction. }

When one of the scaling components is zero, POV-Ray changes this component to 1 since it assumes that 0 means no scaling in this direction. A warning "Illegal Value: Scale X, Y or Z by 0.0. Changed to 1.0." is issued.

## Rotate

You may change the orientation of an object or texture pattern by adding a `rotate`

modifier. It consists of the keyword ` rotate`

followed by a vector expression. The three terms of the vector specify the number of degrees to rotate about each of the x-, y- and z-axes.

**Note:** The order of the rotations does matter. Rotations occur about the x-axis first, then the y-axis, then the z-axis. If you are not sure if this is what you want then you should only rotate on one axis at a time using multiple rotation statements to get a correct rotation.

rotate <0, 30, 0> // 30 degrees around Y axis then, rotate <-20, 0, 0> // -20 degrees around X axis then, rotate <0, 0, 10> // 10 degrees around Z axis.

Rotation is always performed relative to the axis. Thus if an object is some distance from the axis of rotation it will not only rotate but it will *orbit* about the axis as though it was swinging around on an invisible string.

POV-Ray uses a left-handed rotation system. Using the famous *Computer Graphics Aerobics* exercise, you hold up your left hand and point your thumb in the positive direction of the axis of rotation. Your fingers will curl in the positive direction of rotation. Similarly if you point your thumb in the negative direction of the axis your fingers will curl in the negative direction of rotation. See Understanding POV-Ray's Coordinate System for an illustration.

## Matrix

The `matrix`

keyword can be used to explicitly specify the transformation matrix to be used for objects or textures.

Its syntax is:

MATRIX: matrix <Val00, Val01, Val02, Val10, Val11, Val12, Val20, Val21, Val22, Val30, Val31, Val32>

Where * Val00* through

*are float expressions enclosed in angle brackets and separated by commas.*

`Val32`

**Note:** This is not a vector. It is a set of 12 float expressions.

These floats specify the elements of a 4 by 4 matrix with the fourth column implicitly set to `<0,0,0,1>`

. At any given point *P, P=<px, py, pz>*, is transformed into the point *Q, Q=<qx, qy, qz>*
by

qx = Val00 * px + Val10 * py + Val20 * pz + Val30

qy = Val01 * px + Val11 * py + Val21 * pz + Val31

qz = Val02 * px + Val12 * py + Val22 * pz + Val32

Normally you will not use the matrix keyword because it is less descriptive than the transformation commands and harder to visualize. However the matrix command allows more general transformation effects like *shearing*. The following matrix causes an object to be sheared along the y-axis.

object { MyObject matrix < 1, 1, 0, 0, 1, 0, 0, 0, 1, 0, 0, 0 > }